VBScriptをやる機会がありそこで正規表現をやっていた。拡張子がsqlのファイルだけを選択したいと思って正規表現を使おうと思ったのだ。簡単だろうと思ってヘルプも見ずにやってたらやぱい・・・忘れてる。このパターンにたどり着くまでに無駄な時間をすごしてしまった。

.\.sql

*.sqlをやってたのだがこれがだめだってVBScriptのインタープリタに怒られてしまうのだ。ヘルプを見ると・・・

*　－ Matches the preceding character zero or more times. For example, “zo*” matches either “z” or “zoo”.
つまりアスタリスクの直前文字が０回以上が繰り返される文字列にマッチするとあるので、アスタリスクの前に文字がなかったらおかしいのだ。当たり前だよね・・・なんでこんなんで悩んでたんだろう・・・ああ・・・・

C:\Temp\a\b\というようなフォルダを作成したいとき、FileSystemObjectで簡単にできてしまいますが、C:\Temp\aが存在しない状態でbを作ろうとするとエラーになります。そういうようなのをちゃんとサポートしたプロシージャをVBScriptで作りました。必要があったもんで・・・

Sub CreateFolderRecursive(ByVal FolderPath)
    Dim Folders
    Folders = Split(FolderPath, “\”)
    Dim f
    
    Dim FSO
    Set FSO = CreateObject(“Scripting.FileSystemObject”)
    
    Dim FolderToCreate
    For Each f In Folders
        FolderToCreate = FolderToCreate & f & “\”
        
        If Not FSO.FolderExists(FolderToCreate) Then
            FSO.CreateFolder FolderToCreate
        End If
    Next
    
    If Not FSO Is Nothing Then
        Set FSO = Nothing
    End If
End Sub

あるフォルダを除いてすべてを削除するVBScriptのルーティンを作りました。

Sub DeleteExceptFor(ByVal RootFolderPath, ByVal FolderName)
    Dim FSO
    Set FSO = CreateObject(“Scripting.FileSystemObject”)
    
    Dim RootFolder
    Set RootFolder = FSO.GetFolder(RootFolderPath)
    
    Dim folder
    For Each folder In RootFolder.SubFolders
        If LCase(FolderName) <> LCase(folder.Path) Then
            folder.Delete True
        End If
    Next
    
    Dim file
    For Each file In RootFolder.Files
        file.Delete True
    Next
    
    
    If Not FSO Is Nothing Then
        Set FSO = Nothing
    End If
End Sub

中さんのブログでレガシーASPはVisual InterDevがないとデバッグできないとおっしゃっていましたが、前に一度やったことがあるので検証してみました。結論は、できます。ここではWindows Server 2003での検証です。他のOSでは多少違うかもしれません。

1. VS .NETでWeb Applicationのプロジェクトを作り、レファレンスと自動生成されたファイルを全部消す。このステップは特に必要というわけではありません。
   
   
2. 次に自分の好きなASPのファイルを作成する。上の例で、ASPのファイルはC:\Inetpub\wwwroot\ASPDebug\MyASP.aspに存在することになる。
   
3. ASPのコードを書く。もしすでにASPのファイルがあるんだったらWindows Explorerからドラッグアンドドロップでプロジェクトに入れることができます。
   
4. IISを開く。
   
5. Application PoolのノードをクリックしDefaultAppPoolのプロパティをクリックする。
   
   
6. Identityタブをクリックし、Application pool identityをLocal Systemに変えてやる。Local Systemでなくても、Debbuger Usersに属するユーザでもいいと思います。ここでは、簡潔にするためにLocal Systemを使います。更新かＯＫをクリックしてください。
   
   
7. VS .NETに戻って今度はプロジェクトのプロパティを変えてやります。Start Projectは自分がデバッグしたいファイル名。これはソリューションエクスプローラからファイルを右クリックしてスタートページにしてやってもいいです。また、ASP Debuggingをチェックしてやってください。これからもVS .NETはレガシーASPのデバッグをサポートしていることがわかります。
   
   
8. 後はＯＫを押してF5を押してやると、見事デバッグに入ります。（あっ、Break Pointを忘れないでね。）
   
   
9. ちなみにデバッガによってアタッチされているプロセスは下のようになっています。
   

VSSの管理をしててAnalyze VSS DBというのがある。そいつを実行するたびに[VSSInstallFolder]\data\backup\analyze.logのようなファイルを作成し、それを削除しないで再びそのツールを実行すると、「お前、ログファイル消してないだろう！バカもん！」って怒られる。いちいちそのフォルダまで行って削除するのがめんどいので、即VBSｃript・・・スクリプト書くまでもないんですけどね・・・Holiday Seasonはなんか今ひとつガリガリ仕事する気がしなくって。ちょっと気を惑わせるために、ブログしたり、スクリプト書いたり・・・

クリスマスのバカヤロー

Option Explicit

Const LOG_FILE_PATH = “D:\VSS\data\backup\analyze.log”

Call Main()

Sub Main()
    On Error Resume Next
    
    Dim FSO
    Set FSO = CreateObject(“Scripting.FileSystemObject”)
    
    FSO.DeleteFile LOG_FILE_PATH, True
    
    If Not FSO Is Nothing Then
        Set FSO = Nothing
    End If
End Sub

VBScriptを使ってSourceSafeオートメーションに関するクラスを作ってみました。このクラスは実際私のビルドプロセスに使用しています。

Const VSSITEM_PROJECT = 0
Const VSSITEM_FILE = 1

Const VSSFILE_NOTCHECKEDOUT = 0
Const VSSFILE_CHECKEDOUT = 1
Const VSSFILE_CHECKEDOUT_ME = 2

Class SrcSafe
    Private m_SrcSafeDb
    Private m_Result
    Private m_intCount
    Private m_blnDetected
    
    Private Sub Class_Initialize
        m_intCount = 0
        m_blnDetected = False
    End Sub
    
    Public Sub Logon(SrcSafeIniPath, Username, Password)
        Set m_SrcSafeDb = CreateObject(“SourceSafe”)
        m_SrcSafeDb.Open SrcSafeIniPath, Username, Password
    End Sub
    
    Public Sub CheckOutFiles(ByVal ProjectName, ByVal FileList)
        ‘ Checks out files recursively. FileList should be like…
        ‘ AssemblyInfo.vb|AssemblyInfo.cs
        ‘ This function doesn’t support wildcard yet.
        Dim RootNode
        Dim items
        Dim item
        
        Set RootNode = m_SrcSafeDb.VSSItem(ProjectName, False)
        Set items = RootNode.Items(False)
        
        For Each item in items
            If item Is Nothing Then
                Exit For
            End If
            
            If item.Type = VSSITEM_PROJECT Then
                Dim file
                For Each file In item.Items(False)
                    If file.Type = VSSITEM_FILE Then

                        Dim astrFiles
                        astrFiles = Split(FileList, “|”)
                        Dim i
                        For i = 0 To UBound(astrFiles)
                            If UCase(astrFiles(i)) = UCase(file.Name) Then
                                file.CheckOut
                            End If
                        Next

                    End If
                Next
                
                If item.Items(False).Count > 0 Then
                    CheckOutFiles ProjectName & “/” & item.Name, FileList
                End If
            End If ‘ If item.Type = VSSITEM_PROJECT Then
        Next    
    End Sub
    
    Public Sub CheckInAllFiles(ByVal ProjectFolder)

        Dim RootNode
        Dim items
        Dim item
        
        Set RootNode = m_SrcSafeDb.VSSItem(ProjectFolder, False)
        Set items = RootNode.Items(False)
        
        For Each item in items
            If item Is Nothing Then
                Exit For
            End If
            
            If item.Type = VSSITEM_PROJECT Then
                Dim file
                For Each file In item.Items(False)
                    If file.Type = VSSITEM_FILE Then
                        If file.IsCheckedOut = VSSFILE_CHECKEDOUT_ME Then
                            file.CheckIn
                        End If
                    End If
                Next
                
                If item.Items(False).Count > 0 Then
                    CheckInAllFiles ProjectFolder & “/” & item.Name
                End If
            End If ‘ If item.Type = VSSITEM_PROJECT Then
        Next    
    End Sub
    
    
    
    Public Function GetCheckedOutFiles(ByVal ProjectName, ByRef Results)
        Dim RootNode
        Dim items
        Dim item
        
        Set RootNode = m_SrcSafeDb.VSSItem(ProjectName, False)
        Set items = RootNode.Items(False)
        
        For Each item In items
            If item Is Nothing Then
                Exit For
            End If
            
            If item.Type = VSSITEM_PROJECT Then
                Dim file
                Dim objSettings
                Set objSettings = New Settings
                
                For Each file In item.Items(False)
                    If file.Type = VSSITEM_FILE Then
                        If file.IsCheckedOut Then
                            If UCase(file.CheckOuts(1).Username) = UCase(objSettings.SourceSafeUsername) Then
                                m_blnDetected = True
                                m_intCount = m_intCount + 1
                                m_Result = m_Result & m_intCount & “. “ & file.Spec & ” ==> “ & file.CheckOuts(1).LocalSpec & vbCrlf
                            End If
                        End If
                    End If
                Next
                
                If item.Items(False).Count > 0 Then
                    GetCheckedOutFiles ProjectName & “/” & item.Name, m_Result
                End If
            End If
        Next
        Results = m_Result
        GetCheckedOutFiles = m_blnDetected
    End Function
    
    Public Sub GetLatestVersion(ByVal ProjectFolder, ByVal WorkingFolder)
        If m_SrcSafeDb Is Nothing Then
            Err.Raise 1000, “SrcSafe.GetLatestVersion”, “You need to invoke Logon method of SrcSafe Class first.”
            Exit Sub
        End If
        Dim itm
        Set itm = m_SrcSafeDb.VSSItem(ProjectFolder, False)
        itm.Get CStr(WorkingFolder), VSSFLAG_RECURSYES + VSSFLAG_FORCEDIRNO
    End Sub
    
    Private Sub Class_Terminate
        If Not m_SrcSafeDb Is Nothing Then
            Set m_SrcSafeDb = Nothing
        End If
    End Sub
End Class

SQLDMOを使ってVBScriptでいろいろなことができるクラスを書いてみました。以下のことができます。

1. データベースの削除。
   
2. バックアップファイルからのデータベースのRestore（再生）。
   
3. ログインの作成。
   
4. ログインをdb_ownerとしてデータベースに振り分ける。
   
5. ログインが存在するかどうかを確かめる。

他にもいろんなことができるんですが、とりあえずはこのくらいにしておきます。このスクリプトはデータベースアプリを開発されている方に便利なのではないかと思います。

Class SQLServer
    Private m_SQLServer
    
    Private Sub Class_Initialize
        Set m_SQLServer = CreateObject(“SQLDMO.SQLServer”)
    End Sub
    
    Private Sub Class_Terminate
        If Not m_SQLServer Is Nothing Then
            Set m_SQLServer = Nothing
        End If
    End Sub
    
    Public Sub ConnectToSQLServer(ServerName)
        m_SQLServer.LoginSecure = True
        m_SQLServer.Connect CStr(ServerName), vbNullString, vbNullString
    End Sub
    
    Public Sub RemoveDatabase(DatabaseName)
        Dim db
        For Each db In m_SQLServer.Databases
            If UCase(DatabaseName) = UCase(db.Name) Then
                db.Remove
                Exit For
            End If
        Next
    End Sub
    
    Public Sub Disconnect()
        m_SQLServer.DisConnect
    End Sub
    
    Public Sub RestoreDatabase(DatabaseName, PathToDump, PathToDb, PathToLog)
        Dim res
        Set res = CreateObject(“SQLDMO.Restore”)
        res.Action = SQLDMORestore_Database
        res.Files = PathToDump
        
        Dim results
        Set results = res.ReadFileList(m_SQLServer)
        
        Dim strOrigDbName
        Dim strOrigLogName
        strOrigDbName = vbNullString
        strOrigLogName = vbNullString
        
        Dim i
        Dim j
        For i = 1 To results.Rows
            For j = 1 To results.Columns
                ‘ MsgBox results.ColumnName(j) & “: ” & results.GetColumnString(i, j)
                If (results.ColumnName(j) = “LogicalName”) And (i = 1) Then
                    strOrigDbName = results.GetColumnString(i, j)
                End If
                
                If (results.ColumnName(j) = “LogicalName”) And (i = 2) Then
                    strOrigLogName = results.GetColumnString(i, j)
                End If    
            Next
        Next
        
        res.Database = DatabaseName
        res.ReplaceDatabase = True
        
        Dim strRepFile
        strRepFile = “[" & strOrigDbName & "]“
        strRepFile = strRepFile & “,["
        strRepFile = strRepFile & PathToDb
        strRepFile = strRepFile & "\"
        strRepFile = strRepFile & DatabaseName & ".mdf],”
        strRepFile = strRepFile & “[" & strOrigLogName & "],”
        strRepFile = strRepFile & “[" & PathToLog
        strRepFile = strRepFile & "\" & DatabaseName & "_log.ldf]“
        
        res.RelocateFiles = strRepFile
        res.SQLRestore m_SQLServer
        
        ‘ Remove the orphaned users
        RemoveOrphanedUsers(DatabaseName)
    End Sub
    
    Private Sub RemoveOrphanedUsers(DatabaseName)
        Dim db
        Set db = m_SQLServer.Databases.Item(DatabaseName, “”)
        Dim u
        For Each u In db.Users
            If u.Name <> “dbo” Then
                db.Users.Remove(u.Name)            
            End If
        Next
    End Sub
    
    Public Sub AddUserToDatabase(DatabaseName, Username, Password)
        ‘ First, check if Login is there already, if not create one
        Dim login
        Set login = CreateObject(“SQLDMO.Login”)
        login.Name = Username
        login.SetPassword “”, Password
        
        If UserExists(Username) Then
            m_SQLServer.Logins.Remove Username
        End If
        
        login.Database = DatabaseName
        login.Type = SQLDMOLogin_Standard
        
        m_SQLServer.Logins.Add login
        m_SQLServer.Logins.Refresh True
        
        ‘ Create user out of login
        Dim usr
        Set usr = CreateObject(“SQLDMO.User”)
        usr.Name = Username
        usr.Login = Username
        
        m_SQLServer.Databases.Item(DatabaseName, “”).Users.Refresh True
        m_SQLServer.Databases.Item(DatabaseName, “”).Users.Add usr
        Dim Role
        
        Set Role = m_SQLServer.Databases.Item(DatabaseName, “”).DatabaseRoles.Item(“db_owner”)
        Role.AddMember Username
    End Sub
    
    Private Function UserExists(Username)
        Dim usr
        Dim blnResult
        
        blnResult = False
        For Each usr In m_SQLServer.Logins
            If UCase(usr.Name) = UCase(Username) Then
                blnResult = True
                Exit For
            End If
        Next
        
        UserExists = blnResult
    End Function
    
End Class

次回はSourceSafeオートメーションの予定・・・

I have created a class in VBScript that allow you to do basic administration on IIS. So copy and paste the following code in a text file and instantiate the class just like any other object. A sample is available upon request.

Const IIS_PATH = “IIS://localhost/w3svc/1/root”
Const APP_NAME = “My VBScript App”

Class IISAdmin
    Private m_IIS
    
    Private Sub Class_Initialize
        On Error Resume Next
        Set m_IIS = GetObject(IIS_PATH)
        
        If Err.Number <> 0 Then
            MsgBox Err.Description, vbOKOnly + vbExclamation, APP_NAME
            Err.Clear()
            Exit Sub
        End If
    End Sub
    
    Private Sub Class_Terminate
        On Error Resume Next
        
        If Not m_IIS Is Nothing Then
            Set m_IIS = Nothing
        End If
        
        If Err.Number <> 0 Then
            MsgBox Err.Description, vbOKOnly + vbExclamation, APP_NAME
            Err.Clear()
            Exit Sub
        End If
    End Sub
    
    ‘ ******************************************************************
    
    Public Sub CreateVirtualDirectory(ByVal VirDirName, ByVal LocalPath)
        Dim NewVirDir
        Set NewVirDir = m_IIS.Create(“IIsWebVirtualDir”, VirDirName)
        NewVirDir.Path = LocalPath
        NewVirDir.SetInfo
        NewVirDir.AppCreate True
        NewVirDir.SetInfo

        If Not NewVirDir Is Nothing Then
            Set NewVirDir = Nothing
        End If
        
    End Sub
    
    Public Sub DeleteVirtualDirectory(ByVal VirDirName)
        On Error Resume Next
        Dim VirDir
        Set VirDir = m_IIS.Delete(“IIsWebVirtualDir”, VirDirName)
        VirDir.AppDelete
        m_IIS.SetInfo
        Err.Clear()
    End Sub
End Class

が下のURLからアクセスできるようですね。

http://www.microsoft.com/japan/msdn/scripting/default.asp

One of the neatest features with VS .NET 2003 is debugging features. It’s amazing how much effort Microsoft put into debugging, and yes you can debug VBScript as well. I’m going to use the sample I wrote for the previous post for the example here.

First of all, open command line and navigate yourself to where the script exists. And enter the command like the following.

You will immediately prompted to choose a debugger. If you have VS .NET 2003 installed, choose it. It’s far better than Script Editor.

Another dialog box follows the debugger choice. You need to make sure that you check Script in the next dialog box. Once you click on OK button, you are in the debugging mode of VBScript.

You can, of course, put your mouse cursor over variables and check the value of it. You can also set break point and its condition if you want. Locals windows is available, so you can view properties of WScript object on the fly or any other object that you instantiated. Pretty much full debugging feature is available for VBScript. This is great if you are working on a complex batch process you write.

In addition to this Script debugging feature of VS .NET, there is another good news. Intellisense is available for VBScript! Let’s take a look at it here.

I’m going to create a Empty Project using VS .NET 2003 here. Then you add a new item by choosing VBScript to the newly created project.

With me so far? So I’m going to copy and paste the example that I previously wrote and see if intellisense is going to really work.

This is double good news, isn’t it? The intellisense not only lists the VBScript functions and procedures within the file, but it also can list the members of the object you instantiated! FileSystemObject is a COM object, so VS .NET 2003 goes and gets the object meta data of the Class ID (Scripting.FileSystemObject) and lists them for you. If you think VS .NET is cheating, try to instantiate SQLDMO object (class ID = SQLDMO.SQLServer) it and try to see if you can get intellisense for the huge COM object.

On the side note, I have a pretty big script that I distribute to my colleagues for them to refresh their development environment. It developed the script in just a few nights where this debugging feature came in real handy and resulted in quite quick development of quite complex script. Thanks to that, the script is still used after two years.